Как программно добавить кнопку панели инструментов (и обработчик OnClick) в Excel

Как программно добавить панель инструментов (с кнопками) в Excel (2002 или новее)?

Когда нажимается кнопка, я хочу, чтобы обработчик создал мой COM-объект и вызвал на нем метод?

Ответов (2)

Это основа для чего-то, что должно работать в версиях до, но не включая Excel 2007, у которого совершенно другой интерфейс.

Это входит в ваш модуль ThisWorkbook:

Private Sub Workbook_BeforeClose(Cancel As Boolean)
    DeleteCommandBar
End Sub
Private Sub Workbook_Open()
    ShowToolbar
End Sub

И это может быть в том же модуле или в отдельном, на ваш выбор, хотя я предпочитаю поместить его в отдельный модуль, где он может быть более заметным. Вам не нужен OnClick, кнопке сообщается, какую процедуру вызывать, когда вы создаете кнопку.

Private Const TOOLBARNAME = "MyFunkyNewToolbar"

Public Sub ShowToolbar()
' Assumes toolbar not already loaded '
    Application.CommandBars.Add TOOLBARNAME
    AddButton "Button caption", "This is a tooltip", 526, "NameOfASubInYourVBACode"
    ' call AddButton more times for more buttons '
    With Application.CommandBars(TOOLBARNAME)
        .Visible = True
        .Position = msoBarTop
    End With
End Sub

Private Sub AddButton(caption As String, tooltip As String, faceId as Long, methodName As String)
Dim Btn As CommandBarButton
    Set Btn = Application.CommandBars(TOOLBARNAME).Controls.Add
    With Btn
        .Style = msoButtonIcon
        .FaceId = faceId ' choose from a world of possible images in Excel: see http://www.ozgrid.com/forum/showthread.php?t=39992 '
        .OnAction = methodName
        .TooltipText = tooltip
    End With        
End Sub

Public Sub DeleteCommandBar()
    Application.CommandBars(TOOLBARNAME).Delete
End Sub

Вы можете написать надстройку Excel, которая создает панель инструментов с вашей кнопкой и кодом вызова COM , а затем поместить созданный вами файл .xla в папку XLStart пользователя .