Использование MBUnit в TeamCity

Я компилирую проект NAnt на Linux с сервером непрерывной интеграции TeamCity. Мне удалось сгенерировать отчет о тестировании, запустив NAnt в моно через средство запуска командной строки, но у меня нет возможности использовать этот отчет, как средство запуска NAnt. Я также использую MBUnit для тестирования.

Как я могу объединить отчет о тестировании и отобразить «Тесты не пройдены: 1 (1 новый), пройдено: 3049» для сборки?

Обновление: взгляните на MBUnitTask, это задача NAnt, которая использует отправку сообщений, которые TeamCity ожидает от NUnit, поэтому она позволяет вам использовать все функции TeamCity для тестов.

MBUnitTask

Обновление: у Galio лучшая поддержка, поэтому вам просто нужно ссылаться на библиотеки DLL Galio MBUnit 3.5 вместо библиотек DLL MBUnit 3.5 и переключиться на бегун Galio, чтобы заставить его работать.

Ответов (4)

Решение

У Gallio теперь есть расширение для вывода служебных сообщений TeamCity. Просто используйте прилагаемый Gallio.NAntTasks.dll и включите расширение TeamCity. ( в следующем выпуске это не понадобится )

Гаджет боковой панели TeamCity для Windows Vista, Windows 7 http://teamcity-gadget.com

TeamCity следит за выводом командной строки сборки. Вы можете сообщить ему, как проходят ваши тесты, вставив определенные маркеры в эти выходные данные. См. http://www.jetbrains.net/confluence/display/TCD3/Build+Script+Interaction+with+TeamCity . Например

##teamcity[testSuiteStarted name='Test1']

сообщит TeamCity, что начался набор тестов. С помощью MbUnit вы не можете выводить эти маркеры во время выполнения тестов, но вы можете преобразовать XML-файл, который он выводит. Вот XSL, который я использую:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text"/>
    <xsl:template match="/">

        <xsl:apply-templates/>

    </xsl:template>

    <xsl:template match="assemblies/assembly">
##teamcity[testSuiteStarted name='<xsl:value-of select="@name" />']

        <xsl:apply-templates select="//run" />

##teamcity[testSuiteFinished name='<xsl:value-of select="@name" />']
    </xsl:template>

    <xsl:template match="run">

        <xsl:choose>
            <xsl:when test="@result='ignore' or @result='skip'">
        ##teamcity[testIgnored name='<xsl:value-of select="@name" />' message='Test Ignored']
            </xsl:when>
            <xsl:otherwise>
        ##teamcity[testStarted name='<xsl:value-of select="@name" />']
            </xsl:otherwise>
        </xsl:choose>


        <xsl:if test="@result='failure'">
            ##teamcity[testFailed name='<xsl:value-of select="@name" />' message='<xsl:value-of select="child::node()/message"/>' details='<xsl:value-of select="normalize-space(child::node()/stack-trace)"/>']
        </xsl:if>


        <xsl:if test="@result!='ignore' and @result!='skip'">
        ##teamcity[testFinished name='<xsl:value-of select="@name" />']
        </xsl:if>

    </xsl:template>

</xsl:stylesheet>

Вот что я придумал

Как я могу слить отчет об испытаниях?

Сначала вам нужно получить mbunit для создания отчетов в формате XML и HTML. Аргументы командной строки выглядят так

/rt:Xml /rt:Html /rnf:mbunit /rf:..\reports

это создаст отчеты в каталоге с именем reports, а файл будет называться mbunit.xml и mbunit.html

Затем мы хотим добавить эти файлы в качестве артефактов в сборку

build\reports\* => Reports

последний шаг - сказать teamcity, чтобы он добавил его в качестве вкладки для сборки

найдите .BuildServer \ config \ main-config.xml и добавьте эту строку (в Windows это находится в c: \ Documents and Settings \, в Linux это был каталог / root)

<report-tab title="Tests" basePath="Reports" startPage="mbunit.html" />

Как я могу отобразить «Тесты не пройдены: 1 (1 новый), пройдено: 3049» для сборки?

TeamCity ищет файл с именем teamcity-info.xml, в который вы можете вставлять сообщения для отображения. Фактическое количество тестов - это просто обычный текст. Я думаю, вы можете просто добавить файл как артефакт, но он у меня также есть в корневом каталоге сборки.

в NAnt вы захотите использовать эту команду для выполнения XSLT в XML-отчете MBUnit

<style style="includes\teamcity-info.xsl" in="reports\mbunit.xml" out="..\teamcity-info.xml" />

фактический xsl выглядит так. (Примечание: {и} зарезервированы в xsl, поэтому мы должны использовать параметры)

<?xml version="1.0" encoding="ISO-8859-1"?>

<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:param name="cbl" select="'{'"/>
<xsl:param name="cbr" select="'}'"/>
<xsl:template match="/">
<xsl:for-each select="report-result/counter">

<build number="1.0.{concat($cbl,'build.number',$cbr)}">
    <xsl:if test="@failure-count &gt; 0">
        <statusInfo status="FAILURE">    
            <text action="append"> Tests failed: <xsl:value-of select="@failure-count"/>, passed: <xsl:value-of select="@success-count"/></text>
        </statusInfo>
    </xsl:if>
    <xsl:if test="@failure-count = 0">
        <statusInfo status="SUCCESS">
            <text action="append"> Tests passed: <xsl:value-of select="@success-count"/></text>
        </statusInfo>
    </xsl:if>

</build>
</xsl:for-each>

</xsl:template>
</xsl:stylesheet>

Это даст вам файл, который выглядит так

<build number="1.0.{build.number}">
   <statusInfo status="FAILURE">
      <text action="append">Tests failed: 16, passed: 88</text>
   </statusInfo>
</build>