Можете ли вы заставить либо скалярную ссылку, либо ссылку на массив быть массивом в Perl?

У меня есть переменная perl $results, возвращаемая службой. Значение должно быть массивом и $results должно быть ссылкой на массив. Однако, когда в массиве есть только один элемент, $results будет установлено это значение, а не ссылочный массив, содержащий этот один элемент.

Я хочу выполнить foreach цикл для ожидаемого массива. Без проверки ref($results) eq 'ARRAY', есть ли способ получить что-то эквивалентное следующему:

foreach my $result (@$results) {
    # Process $result
}

Этот конкретный пример кода будет работать для справки, но будет жаловаться на простой скаляр.

РЕДАКТИРОВАТЬ: я должен уточнить, что у меня нет возможности изменить то, что возвращается из службы. Проблема в том, что значение будет скаляром, когда есть только одно значение, и будет ссылкой на массив, когда есть более одного значения.

Ответов (6)

Решение

Я не уверен, что есть другой способ, кроме:

$result = [ $result ]   if ref($result) ne 'ARRAY';  
foreach .....

Я только что протестировал это с помощью:

#!/usr/bin/perl -w
use strict;

sub testit {

 my @ret = ();
 if (shift){
   push @ret,1;
   push @ret,2;
   push @ret,3;
}else{
  push @ret,"oneonly";
}

return \@ret;
}

foreach my $r (@{testit(1)}){
  print $r." test1\n";
}
foreach my $r (@{testit()}){
   print $r." test2\n";
}

И, похоже, он работает нормально, поэтому я думаю, что это как-то связано с результатом, возвращаемым службой? Если у вас нет контроля над службой возврата, это может быть сложно взломать

Сделать это можно так:

my @some_array
push (@some_array, results);
foreach my $elt(@some_array){
  #do something
}

Я бы повторно разложил код внутри цикла, а затем сделал бы

if( ref $results eq 'ARRAY' ){
    my_sub($result) for my $result (@$results);
}else{
    my_sub($results);
}

Конечно, я бы сделал это только в том случае, если бы код в цикле был нетривиальным.

Другим решением было бы обернуть вызов на сервер и заставить его всегда возвращать массив, чтобы упростить оставшуюся жизнь:

sub call_to_service
{
    my $returnValue = service::call();

    if (ref($returnValue) eq "ARRAY")
    {
        return($returnValue);
    }
    else
    {
       return( [$returnValue] );
    }
}

Тогда вы всегда можете быть уверены, что получите ссылку на массив, даже если это был только один элемент.

foreach my $item (@{call_to_service()})
{
  ...
}

Что ж, если ты не можешь ...

for my $result ( ref $results eq 'ARRAY' ? @$results : $results ) {
    # Process result
}

или это...

for my $result ( ! ref $results ? $results : @$results ) {
    # Process result
}

тогда тебе, возможно, придется попробовать что-нибудь такое страшное, волосатое! ....

for my $result ( eval { @$results }, eval $results ) {
    # Process result
}

и чтобы избежать этой опасной строки eval, она становится действительно уродливой !! ....

for my $result ( eval { $results->[0] } || $results, eval { @$results[1 .. $#{ $results }] } ) {
    # Process result
}

PS. Я бы предпочел абстрагироваться от этого в примере sub ala call_to_service (), предоставленном reatmon.