Получение текущего вошедшего в систему пользователя ОС в Adobe Air

Мне нужно имя текущего зарегистрированного пользователя в моем приложении Air / Flex . Приложение будет развернуто только на компьютерах с Windows. Я думаю, что смогу добиться этого путем регулярного выражения каталога User, но я открыт для других способов.

Ответов (5)

Также я бы попробовал:

File.userDirectory.name

Но у меня не установлен Air, поэтому я не могу это проверить ...

Вот решение, которое работает в XP / Vista, но определенно может быть расширено до OSX, linux, меня все равно заинтересует другой способ.

public static function GetCurrentOSUser():String{
    // XP & Vista only.
    var userDirectory:String = File.userDirectory.resolvePath("").nativePath;
    var startIndex:Number = userDirectory.lastIndexOf("\\") + 1
    var stopIndex:Number = userDirectory.length;
    var user = userDirectory.substring(startIndex, stopIndex);

    return user;
}

Вы можете сделать пару небольших уборок ...

package
{
    import flash.filesystem.File;

    public class UserUtil
    {
        public static function get currentOSUser():String
        {
            var userDir:String = File.userDirectory.nativePath;
            var userName:String = userDir.substr(userDir.lastIndexOf(File.separator) + 1);
            return userName;
        }
    }
}

Как предложил Кевин, используйте, File.separator чтобы сделать разделение каталогов кросс-платформенным (только что протестировано в Windows и Mac OS X).

Вам не нужно использовать, resolvePath("") если вы не ищете ребенка.

Кроме того, создание функции надлежащего получателя позволяет выполнять привязку без какой-либо дополнительной работы.

В приведенном выше примере я поместил его в UserUtil класс, теперь я могу выполнить привязку UserUtil.currentOSUser, например:

<?xml version="1.0" encoding="utf-8"?>
<mx:WindowedApplication xmlns:mx="http://www.adobe.com/2006/mxml" layout="absolute">
    <mx:Label text="{UserUtil.currentOSUser}"/> 
</mx:WindowedApplication>

Обновите способ позже: на самом деле есть встроенная функция для получения текущего пользователя. Думаю дело в родном приложении.

Это не самый красивый подход, но если вы знаете, что ваше приложение AIR будет запускаться только в среде Windows, оно работает достаточно хорошо:

public var username:String;

public function getCurrentOSUser():void
{       
   var nativeProcessStartupInfo:NativeProcessStartupInfo = new NativeProcessStartupInfo();  
   var file:File = new File("C:/WINDOWS/system32/whoami.exe");
   nativeProcessStartupInfo.executable = file;

   process = new NativeProcess();       
   process.addEventListener(ProgressEvent.STANDARD_OUTPUT_DATA, onOutputData);
   process.start(nativeProcessStartupInfo);
}

public function onOutputData(event:ProgressEvent):void
{           
   var output:String = process.standardOutput.readUTFBytes(process.standardOutput.bytesAvailable);
   this.username = output.split('\\')[1];
   trace("Got username: ", this.username);
}