Как отключить все текущие подключения к базе данных SQL Server 2005?

Select 'Kill '+ CAST(p.spid AS VARCHAR)KillCommand into #temp
from master.dbo.sysprocesses p (nolock)
join master..sysdatabases d (nolock) on p.dbid = d.dbid
Where d.[name] = 'your db name'

Declare @query nvarchar(max)
--Select * from #temp
Select @query =STUFF((                              
            select '  ' + KillCommand from #temp
            FOR XML PATH('')),1,1,'') 
Execute sp_executesql @query 
Drop table #temp

используйте «главную» базу данных и запустите этот запрос, он убьет все активные соединения из вашей базы данных.

ALTER DATABASE [Test]
SET OFFLINE WITH ROLLBACK IMMEDIATE

ALTER DATABASE [Test]
SET ONLINE

В этом сценарии у меня работает следующий вариант:

1. Запустите операцию «Отсоединить» от рассматриваемой базы данных. Это откроет окно (в SQL 2005), отображающее активные соединения, которые предотвращают действия с БД.
2. Убейте активные соединения, отмените операцию отсоединения.
3. База данных теперь должна быть доступна для восстановления.

У меня это не сработало (SQL2008 Enterprise), я также не видел никаких запущенных процессов или пользователей, подключенных к БД. Перезапуск сервера (щелкните правой кнопкой мыши на сервере Sql в Management Studio и выберите «Перезагрузить») позволил мне восстановить БД.

Вы можете использовать команду SP_Who и убить все процессы, которые используют вашу базу данных, а затем переименовать вашу базу данных.

Я использую SQL Server 2008 R2, моя БД уже была настроена для одного пользователя, и было соединение, которое ограничивало любые действия с базой данных. Таким образом, рекомендованное решение SQLMenace ответило ошибкой. Вот тот, который сработал в моем случае .

В MS SQL Server Management Studio в проводнике объектов щелкните правой кнопкой мыши базу данных. В следующем контекстном меню выберите «Задачи -> Перевести в автономный режим».

Я всегда использовал:

ALTER DATABASE DB_NAME SET SINGLE_USER WITH ROLLBACK IMMEDIATE 
GO 
SP_RENAMEDB 'DB_NAME','DB_NAME_NEW'
Go 
ALTER DATABASE DB_NAME_NEW  SET MULTI_USER -- set back to multi user 
GO 

Попробуй это:

ALTER DATABASE [DATABASE_NAME]
SET SINGLE_USER
WITH ROLLBACK IMMEDIATE

Использование SQL Management Studio Express:

В дереве обозревателя объектов развернитесь в разделе «Управление» до «Монитор активности» (если вы не можете найти его там, щелкните правой кнопкой мыши сервер базы данных и выберите «Монитор активности»). Открыв Activity Monitor, вы можете просмотреть всю информацию о процессе. Вы должны быть в состоянии найти блокировки для интересующей вас базы данных и снять эти блокировки, что также приведет к уничтожению соединения.

После этого вы сможете переименовать.

Сценарий для этого замените DB_NAME на базу данных, чтобы уничтожить все подключения к:

USE master
GO

SET NOCOUNT ON
DECLARE @DBName varchar(50)
DECLARE @spidstr varchar(8000)
DECLARE @ConnKilled smallint
SET @ConnKilled=0
SET @spidstr = ''

Set @DBName = 'DB_NAME'
IF db_id(@DBName) < 4
BEGIN
PRINT 'Connections to system databases cannot be killed'
RETURN
END
SELECT @spidstr=coalesce(@spidstr,',' )+'kill '+convert(varchar, spid)+ '; '
FROM master..sysprocesses WHERE dbid=db_id(@DBName)

IF LEN(@spidstr) > 0
BEGIN
EXEC(@spidstr)
SELECT @ConnKilled = COUNT(1)
FROM master..sysprocesses WHERE dbid=db_id(@DBName)
END

Я обычно сталкиваюсь с этой ошибкой, когда пытаюсь восстановить базу данных. Обычно я просто перехожу к вершине дерева в Management Studio, щелкаю правой кнопкой мыши и перезапускаю сервер базы данных (поскольку он находится на машине разработки, это может быть не идеально в производственной среде. ). Это закрывает все соединения с базой данных.

Убей его, и убей его огнем:

USE master
go

DECLARE @dbname sysname
SET @dbname = 'yourdbname'

DECLARE @spid int
SELECT @spid = min(spid) from master.dbo.sysprocesses where dbid = db_id(@dbname)
WHILE @spid IS NOT NULL
BEGIN
EXECUTE ('KILL ' + @spid)
SELECT @spid = min(spid) from master.dbo.sysprocesses where dbid = db_id(@dbname) AND spid > @spid
END

Вот как надежно сделать это в MS SQL Server Management Studio 2008 (может работать и для других версий):

1. В дереве обозревателя объектов щелкните правой кнопкой мыши корневой сервер базы данных (с зеленой стрелкой), затем щелкните монитор активности.
2. Откройте вкладку процессов в мониторе активности, выберите раскрывающееся меню «базы данных» и отфильтруйте нужную базу данных.
3. Щелкните правой кнопкой мыши базу данных в обозревателе объектов и запустите задачу «Задачи -> Перевести в автономный режим». Оставьте это работать в фоновом режиме, пока вы ...
4. Безопасно выключите все, что сможете.
5. Убейте все оставшиеся процессы на вкладке процессов.
6. Верните БД в оперативный режим.
7. Переименуйте БД.
8. Верните свою службу в оперативный режим и укажите ее в новой БД.

Щелкните правой кнопкой мыши имя базы данных, щелкните «Свойство», чтобы открыть окно свойств, откройте вкладку «Параметры» и измените свойство «Ограничить доступ» с «Многопользовательский» на «Однопользовательский». Когда вы нажмете кнопку ОК, вам будет предложено закрыть все открытые соединения, выберите «Да», и вы настроены на переименование базы данных ....

Переход в автономный режим занимает некоторое время, и иногда у меня возникают проблемы с этим ..

Самый надежный способ на мой взгляд:

Отключить Щелкните правой кнопкой мыши DB -> Задачи -> Отключить ... отметьте "Drop Connections" Ok

Повторно подключите Щелкните правой кнопкой мыши "Базы данных" -> "Присоединить .. Добавить ..." -> выберите свою базу данных и измените столбец "Присоединить как" на желаемое имя базы данных. Ok

Другой подход «убить его огнем» - просто перезапустить службу MSSQLSERVER. Мне нравится делать что-то из командной строки. Вставка этого точно в CMD сделает это: NET STOP MSSQLSERVER и NET START MSSQLSERVER

Или откройте «services.msc» и найдите «SQL Server (MSSQLSERVER)» и щелкните правой кнопкой мыши, выберите «перезапустить».

Это "наверняка, наверняка" уничтожит ВСЕ подключения ко ВСЕМ базам данных, работающим на этом экземпляре.

(Мне это нравится больше, чем многие подходы, которые изменяют и меняют конфигурацию на сервере / базе данных)

Я использую sp_who, чтобы получить список всех процессов в базе данных. Это лучше, потому что вы можете проверить, какой процесс убить.

declare @proc table(
    SPID bigint,
    Status nvarchar(255),
    Login nvarchar(255),
    HostName nvarchar(255),
    BlkBy nvarchar(255),
    DBName nvarchar(255),
    Command nvarchar(MAX),
    CPUTime bigint,
    DiskIO bigint,
    LastBatch nvarchar(255),
    ProgramName nvarchar(255),
    SPID2 bigint,
    REQUESTID bigint
)

insert into @proc
exec sp_who2

select  *, KillCommand = concat('kill ', SPID, ';')
from    @proc

Результат
Вы можете использовать команду в столбце KillCommand, чтобы убить процесс, который вы хотите.

SPID    KillCommand
26      kill 26;
27      kill 27;
28      kill 28;